[Resolvido] - Ajuda a criar codigo.

[Tatia 0]

Boas amigo, estou a querer criar um mini programa para enviar arquivos para mail, o problema e que não faço a mínima ideia de como começar o código porque não sei que nomes pesquisar para fazer o código vou deixar o designer da aplicação e o que pretendo fazer bem detalhado para ver se me podem ajudar com mais facilidade...

Dados do forum:

Essa informação seria enviada num arquivo de texto para que possa identificar o usuário de x site...

Observação:

Essa informação seria colocada no mesmo arquivo de texto de (Dados de forum)

Ficheiro .rar or .zip:

Ai seria onde o usuário colocaria os seus ficheiros a enviar.

Botão enviar para enviar toda essa informação para mail.

Poderiam me ajudar a criar isto por favor?

EDITE: [Resolvido]

Editado 13 de Agosto de 2013 por Tatia

[nelsonr 337]

Boas,

para enviares um email, usas algo assim:

Private Sub Button9_Click(sender As Object, e As EventArgs) Handles Button9.Click
	Dim mailMessage As New MailMessage

	' Propriedades da mensagem
	mailMessage.From = New MailAddress("from@mail.pt")
	mailMessage.To.Add("to@mail.pt")
	mailMessage.IsBodyHtml = True
	mailMessage.Subject = "Assunto da mensagem"
	mailMessage.Body = "Texto da mensagem<br />" &
		"Linha 2 do texto"

	' Ficheiros a anexar
	mailMessage.Attachments.Add(New Attachment("C:\ficheiro.txt"))

	' Servidor de envio
	Dim SMTP As New SmtpClient("smtp.servidor.pt")
	' Definir credenciais (caso necessário)
	' SMTP.UseDefaultCredentials = False
	' Dim credentials As New NetworkCredential("utilizador", "password")
	' SMTP.Credentials = credentials
	Try
		' Tentar enviar mensagem
		SMTP.Send(mailMessage)
		'
		MessageBox.Show("Email enviado correctamente", Me.Text, MessageBoxButtons.OK, MessageBoxIcon.Information)
	Catch ex As Exception
		MessageBox.Show("Ocorreu um erro ao tentar enviar email" & vbCr & vbCr & ex.Message, Me.Text, MessageBoxButtons.OK, MessageBoxIcon.Error)
	End Try
End Sub

Tens de substituir os dados pelos do teu servidor de envio (SMTP).

Caso o servidor de envio precise de autenticação, retira as linhas em destaque de comentário e coloca o utilizar e password

A mensagem está definida como envio do corpo em HTML. Isso facilita a formatação do conteúdo (se quiseres outras fontes, ou bold, italico, etc)

[Tatia 0]

Private Sub Button4_Click(sender As Object, e As EventArgs) Handles Button4.Click
	Dim mailMessage As New MailMessage
	mailMessage.From = New MailAddress("****")
	mailMessage.To.Add("*************@gmail.com")
	mailMessage.IsBodyHtml = True
	mailMessage.Subject = TextBox1.Text & Label6.Text & TextBox2.Text
	mailMessage.Body = TextBox3.Text
	mailMessage.Attachments.Add(New Attachment(TextBox4.Text))
	Dim SMTP As New SmtpClient("smtp.gmail.com")
	SMTP.Port = 587
	Dim credenciais As New System.Net.NetworkCredential
	credenciais.UserName = "***********@gmail.com"
	credenciais.Password = "*********************"
	SMTP.EnableSsl = True
	SMTP.UseDefaultCredentials = False
	SMTP.Credentials = credenciais
	Try
		SMTP.Send(mailMessage)
		MessageBox.Show("Email enviado correctamente", Me.Text, MessageBoxButtons.OK, MessageBoxIcon.Information)
	Catch ex As Exception
		MessageBox.Show("Ocorreu um erro ao tentar enviar email" & vbCr & vbCr & ex.Message, Me.Text, MessageBoxButtons.OK, MessageBoxIcon.Error)
	End Try
	    SMTP.Dispose()
End Sub

Edite 2:

Bom afinal não foi assim tão difícil de criar isto, agora estou e preocupado com a segurança do meu mail e pass...

Como posso encriptar todo o código para que terceiros não roubem a minha pass?

Editado 12 de Agosto de 2013 por Tatia